How can we help? 👋

What Do the State Property’s Symbols Mean?

Learn about the useful State property in Task views.

Last updated on May 6, 2022

The State property shows up on most Task Manager views in Ultimate Brain:

 
Notion image
 

These symbols provide useful information about your tasks at a glance. Here’s what each symbol means:

 
  • 😄 = Done (should only show on Completed views, or if you click Done on a recurring task instead of moving its Due Date)
  • ⚪️ = No due date
  • 🟢 = Due today
  • 🔴 = Overview
  • 🔵 = Due after today
  • ➞ = this is a sub-task
 

In addition to providing quick info about your tasks, the State property is used extensively within Ultimate Brain’s filters (mostly to control where sub-tasks are displayed). For this reason, it is extremely important to never delete this property.

Hide the State Property

If you want to hide the State view, you can access each Task view’s View Options, navigate to Properties, and then toggle the show/hide icon for the State property.

 
Notion image

State Property Formula

The State property is driven by a relatively simple Notion formula:

 
if(empty(prop("Parent Task")), "", "➞") + if(prop("Done") == true, "😀", if(empty(prop("Due")), "⚪️", if(formatDate(prop("Due"), "L") == formatDate(now(), "L"), "🟢", if(prop("Due") < now(), "🔴", "🔵"))))
 

Here’s an expanded version of the formula with explanations:

 
if(
	/* if there's no parent task, */
	empty(prop("Parent Task")),
	
	/* don't add anything here. */
	"",
	
	/* otherwise, if there is one, add an arrow. */
	"➞")

+

if(
	/* if "Done" is checked, */
	prop("Done") == true,
	
	/* output a smiley face. */
	"😀",
	
	if(
		/* if it's not checked, look for a due date. */
		empty(prop("Due")),
	
		/* if there's not a due date, output a white circle. */
		"⚪️",
	
		if(
			/* if there is a due date, check whether it's today. the "L" format is used here to avoid taking time into account. */
			formatDate(prop("Due"), "L") == formatDate(now(), "L"),
	
			/* if it's due today, output a green circle. */
			"🟢",

			if(
				/* if it's not due today, check if it's overdue. */
				prop("Due") < now(),

				/* if it's overdue, output a red circle. */
				"🔴",
	
				/* finally, if it's not overdue, output a blue circle. */
				"🔵"
			)
		)
	)
)
 

Hopefully this will help in the case that you’d like to modify the formula!

Did this answer your question?
😞
😐
🤩